More scripting help.

[Anonlol]

Because its being really stupid. From memory;

#if
checkitem rustedbrace(s)
#act
goto check1
#elsesay
Not the correct items!
 
[@check1]
#act
take rustedbrace(s)
take gold 20000
#if
random 30
#act
give DemiseBrace
#elseact
Sendmsg 6 "The item was destroyed"

I did this script last night, anyone can click on the NPC without having the item.. it takes the gold, and displays the message the item was destroyed. Its like its not even doing the first check to see if the player has the item and just skipping to the second part.

I'll take another look tonight but am I doing something stupidly worng on something so simple?

 

[hustler]

[@main]
#IF
checkitem rustedbrace(s) 1
#ACT
goto @check1
#ELSESAY
Not the correct items!\ \
<Exit/@exit>

[@check1]
#ACT
take rustedbrace(s) 1
take gold 20000
#IF
random 30
#ACT
give DemiseBrace 1
#ELSEACT
Sendmsg 6 "The item was destroyed."

Try this.

h

 

[mStation]

i guess it would be something like this:

[@main]
#if
CHECKITEM RustedBrace(s) 1
#act
goto check1
#elsesay
Not the correct items!

[@check1]
#if
random 30
#act
TAKE RustedBrace(s) 1
TAKE gold 20000
GIVE DemiseBrace 1
#elseact
TAKE RustedBrace(s) 1
TAKE gold 20000
Sendmsg 6 "The item was destroyed"

 

[Bon]

#IF
checkitem rustedbrace(s) 1
#ACT
goto @check1
break
#ELSESAY
You do not have the correct item, sorry!\ \
<Back/@main>
 
[@check1]
#IF
CHECKGOLD 20000
#ACT
goto @check2
break
#ELSESAY
Sorry you do not have enough gold...\ \
<Back/@main>


[@check2]
#IF
RANDOM 30
#ACT
take rustedbrace(s) 1
take gold 20000
Sendmsg 6 "The item was destroyed... Bad luck!"
break
#SAY
It appears the item has broke.. Im sorry\ \ \
<Back/@main>

#ELSEACT
take rustedbrace(s) 1
take gold 20000
give DemiseBrace 1
Sendmsg 6 "The item crafting was a success!! Enjoy your new item!"
#SAY
The item crafting was a success!! Enjoy your new item!\ \

thats the correct way to do it, the rest of the scripts posted havnt even checked for the gold... of course u could shorten it by just doing this

#IF
checkitem rustedbrace(s) 1
CHECKGOLD 20000
#ACT
goto @check1
break
#ELSESAY
You do not have the correct item, or enough gold, sorry!\ \

[@check1]
#IF
RANDOM 30
#ACT
take rustedbrace(s) 1
take gold 20000
#SAY
It appears the item has broke.. Im sorry\ \ \
<Back/@main>

#ELSEACT
take rustedbrace(s) 1
take gold 20000
give DemiseBrace 1
#SAY
The item crafting was a success!! Enjoy your new item!\

 

[Anonlol]

Cheers, fixed, all I needed to do was add the 1s, was assuming that if I didnt specify an amount itd default to 1 anyways

 

[mStation]

tbh if you want to do something nice and clean you should follow ben's post since he wrote a script much better..

 

[Anonlol]

I ried it like that the first time, it didnt work so I broke it all up.

It works, so im happy, its only me thats going to see it

 

[Bon]

well make sure u do actually check for the gold....... not just take it away